0 REM *********************************
1 REM *                               *
2 REM *       **  HIRN 64  **         *
3 REM *                               *
4 REM *           1986 BY             *
5 REM *        WILHELM TODTER         *
6 REM *       EISENHANDSTR. 23        *
7 REM *         A-4020 LINZ           *
8 REM *                               *
9 REM *********************************
10 REM
11 REM *      HYPRA-BASIC MODULE:                   2, 3, 21, 31, 34, ??71??
12 REM
100 POKE53280,6:POKE53281,6:POKE646,7:AW=RND(-TI):PRINTCHR$(14)
109 REM * ERWEITERUNG LADEN UND STARTEN
110 IFPEEK(49152)=169ANDPEEK(49153)=11ANDPEEK(49154)=141ANDPEEK(49155)=8THEN130
120 PRINTCHR$(147);"[204]OADING ...":LOAD"HIRN.ERW",8,1
129 REM * VARIABLE VORDEFINIEREN
130 SYS49152:JO=56320:SP=14:ZL=22:FE=0:FB=8:FA=1:DIMFA(6),FE(4)
132 P1$=CHR$(5)+"^":P2$=CHR$(5)+"_":LI$=CHR$(155)+"[192]"
140 FORI=1TO6:READFA(I):NEXT
141 DATA 7,2,4,14,3,5
150 T1$="[158]*[200][156][201][154][210][159][206]*":T2$="*[159]+[154]6[156]4+[158]*":T3$="[158]*H[156]I[154]R[159]N*"
160 LE$="                                       "
199 REM * TITELBILD
200 PRINTCHR$(147):FRAME0:BACK0:PEN15:RECLOW0,0,40,25,15:RECLOW1,1,38,23,15
210 BIG4,8,T1$:BIG9,8,T2$:SET9,15,"1986 BY [215]ILHELM [212]ODTER":INVERS14,8,16,31
220 SET8,19,"[208]RESS <[210][197][212][213][210][206]> TO START":BLINK 19,14,19,21,200
230 GETI$:IFI$<>CHR$(13)THEN220
299 REM * SPIELFELDAUFBAU
300 PRINTCHR$(142);CHR$(147):PEN15
310 SET15,0,"[176][192][178][192][178][192][178][192][174]":SET15,1,"[221]?[155][221]?[155][221]?[155][221]?[155][221]"
320 FORI=2TO20STEP2:SET15,I,"[171][192][219][192][219][192][219][192][179]":SET15,I+1,"[221][215][221][215][221][215][221][215][221]":NEXT
330 SET15,22,"[173][192][177][192][177][192][177][192][189]":PEN1:SET6,1,"*WT*";:SET30,1,"*86*";
340 FORI=0TO5:BIGI*4,0,MID$(T3$,2*I+1,2):BIGI*4,36,MID$(T2$,2*I+1,2):NEXT
350 FORI=0TO5:PENFA(I+1):SET8,8+I,CHR$(175):NEXT:INVERS8,8,13,8
360 PEN1:SETSP,ZL,"^":SET9,FB,"_":PEN15
362 SE$="*LOESCHEN*":FORI=1TO10:SET13,2*I,MID$(SE$,I,1):NEXT:SLINE1,12,21,15
364 SE$="*BEWERTEN*":FORI=1TO10:SET25,2*I,MID$(SE$,I,1):NEXT:SLINE1,26,21,15
369 REM * FARBCODE DURCH ZUFALLSZAHLEN
370 SE$="* ICH LOSE DIE FARBEN AUS *":GOSUB1000
380 FORI=1TO4:CO(I)=FA(INT(6*RND(1))+1):NEXT
400 PEN15:SE$="* AUF GEHT'S! *":GOSUB1000
409 REM * EINGABESCHLEIFE
410 DO:JY=PEEK(JO):GETSE$:IFSP<>24THEN:SET24,ZL,CHR$(32)
412 IFSP<>14THEN:SET14,ZL,CHR$(32)
419 REM * FELDAUSWAHL
420 IFJY=123ANDSP>14THENSP=SP-2:SETSP,ZL,P1$:FE=FE-1:IFSP<22THEN:SETSP+2,ZL,LI$
430 IFJY=119ANDSP<24THENSP=SP+2:SETSP,ZL,P1$:FE=FE+1:IFSP>16THEN:SETSP-2,ZL,LI$
439 REM * FARBAUSWAHL
440 IFJY=126ANDFB>8THENFB=FB-1:SET9,FB,P2$:SET9,FB+1,CHR$(32):FA=FA-1
450 IFJY=125ANDFB<13THENFB=FB+1:SET9,FB,P2$:SET9,FB-1,CHR$(32):FA=FA+1
460 LOOP UNTIL JY<119ORSE$=CHR$(133)
464 REM * F1 = AUFGABE
465 IFSE$=CHR$(133)THEN800
469 REM * FARBE SETZEN
470 IFSP>14ANDSP<24THEN:PENFA(FA):SETSP,ZL-1,"[209]";:FE(FE)=FA(FA):GOTO410
480 IFSP=14THEN:PEN15:SET16,ZL-1,"[215][215][215][215]":FORI=1TO4:FE(I)=0:NEXT:GOTO410
499 REM * AUSWERTUNG EINER ZEILE
500 SE$="* MAL SEHEN ... *":GOSUB1000
509 REM * NICHT ALLE FELDER GESETZT
510 FL=0:FORI=1TO4:IFFE(I)=0THENFL=1
520 NEXT:IFFL=1THEN:SE$="* SO ABER NICHT!! *":GOSUB1000:GOTO400
529 REM * CODEZEILE KOPIEREN
530 FORI=1TO4:FV(I)=CO(I):NEXT
539 REM * FARBE UND POSITION RICHTIG
540 FW=0:FORI=1TO4:IFFE(I)=FV(I)THENFW=FW+1:FE(I)=0:FV(I)=-1
542 NEXT:IFFW>0THEN:PEN1:FORI=1TOFW:SET28+I,ZL-1,"*":NEXT
549 REM * NUR FARBE RICHTIG
550 FG=0:FORI=1TO4:FORJ=1TO4:IFFE(I)=FV(J)THENFG=FG+1:FE(I)=0:FV(J)=-1
552 NEXT:NEXT:IFFG>0THEN:PEN15:FORI=1TOFG:SET28+FW+I,ZL-1,"+":NEXT
560 SP=16:ZL=ZL-2:PEN1:SET24,ZL+2,CHR$(32):FE=1
569 REM * SPIEL BEENDET?
570 IFFW<4ANDZL>2THEN:SETSP,ZL,"^":GOTO400
579 REM * SPIELENDE - CODE ZEIGEN
580 FORI=1TO4:PENCO(I):SET14+2*I,1,"[209]":NEXT:IFFW=4THEN600
589 REM * VERLOREN
590 PEN15:SE$="* MEIN TIP: UEBEN, UEBEN ... *":GOSUB1000:GOSUB1100:RUN
599 REM * GEWONNEN
600 PEN15:IFZL=20THENSE$="* PH! REINER ZUFALL! *"
610 IFZL=18ORZL=16THENSE$="* NA JA, MIT GLUECK... *"
620 IFZL=14ORZL=12THENSE$="* BIST JA EIN MITDENKER! *"
630 IFZL=10ORZL=8THENSE$="* AUCH NICHT SCHLECHT! *"
640 IFZL=6ORZL=4ORZL=2THENSE$="* DAS GEHT NOCH BESSER! *"
650 GOSUB1000:GOSUB1100:RUN
799 REM * AUFGEGEBEN
800 FORI=1TO4:PENCO(I):SET14+2*I,1,"[209]":NEXT
810 PEN15:SE$="* AUFGEGEBEN *":GOSUB1000:GOSUB1100:RUN
999 REM * KOMMENTARZEILE AUSGEBEN
1000 SET0,24,LE$;:SET20-LEN(SE$)/2,24,SE$;:POKE162,200
1010 IFPEEK(162)THEN1010
1020 RETURN
1099 REM * KOMMENTARZEILE BLINKEN
1100 BLINK24,19-LEN(SE$)/2,24,21+LEN(SE$)/2,200:RETURN